Been trying to extract some textures and sprites from a mobile game I used to play, and I'm very close but I have no idea what to do from here.
Using hxd, I was able to find hundreds of .ktx, .pvr, and .dds files stored inside a single .mp3 file called "content.mp3", located in the /assets/ folder of the .apk
I have no idea how to decompress .mp3 files or get the files out, so I've attached the file here in hopes that someone else here will be able to help out. Thanks!

content.mp3 (file is 34.7MB so I can't attach it directly) : https://drive.google.com/file/d/1_ixdTbhHgllyaAJAq27RiIKfjli6GYm9/view?usp=sharing

Edited July 8, 20242 yr by lumbud84

Here's a QuickBMS script to extract the files off it
 

## Big Win Racing (mobile) - content.mp3 extractor script by BloodRaynare

IDstring "\x4f\xf3\x2f\xac"
get UNK long
get NAME_ENTRY_SZ long
get FILES long
savepos NAME_ENTRY_OFF
xmath TOC_ENTRY_OFF "NAME_ENTRY_OFF + NAME_ENTRY_SZ"

goto TOC_ENTRY_OFF

for i = 0 < FILES
	math CUR_PATH_POS = 0
	math CUR_FNAME_POS = 0
	
	get PATH_OFF long
	get FNAME_OFF long
	get CMP_FLAG long
	if CMP_FLAG == 2
		comtype lzma_dynamic
	else
		comtype deflate
	endif
	get OFFSET long
	get SIZE long
	get ZSIZE long
	savepos CUR_TOC_POS
	xmath CUR_PATH_POS "NAME_ENTRY_OFF + PATH_OFF" 
	xmath CUR_FNAME_POS "NAME_ENTRY_OFF + FNAME_OFF"
	goto CUR_PATH_POS
	get PATH string
	goto CUR_FNAME_POS
	get FNAME string
	string NAME p "%s/%s" PATH FNAME
	if CMP_FLAG > 0
		clog NAME OFFSET ZSIZE SIZE
	else
		log NAME OFFSET ZSIZE
	endif
	goto CUR_TOC_POS
next i

 

Thank you so much! ^^