Can anyone make a BMS script that'll unpack the data of those files from that game?
DL link for the files. https://www.dropbox.com/scl/fo/18qikwh9z51p5t7d7rbqi/ALvzD-JzWL7LL2pdu_C35Ws?rlkey=uv85p669svvbvx4u0ec2vzqf6&dl=0

Here's BMS script for your files:

# Neon Genesis Evangelion - Eva and Her Funny Friends: Stripping Complementary Plan! (PC) PAC extractor script by BloodRaynare
# For use with QuickBMS

idstring "\x83\x47\x83\x94\x83\x40\x96\x83\x90\x9D\x83\x66\x81\x5B\x83\x5E"
get unknownValue long
get entries long
get dataAllSize long
getdstring zero 36
xmath entriesBeforeLast "entries - 1"

for i = 0 < entries
	get offset long
	putarray 0 i offset
next i

for i = 0 < entries
	getarray offset 0 i
	math i + 1
	if i == entries
		getarray relOffset 0 0
		math offset + relOffset
		xmath size "(dataAllSize + relOffset) - offset"
	else
		getarray nextOffset 0 i
		if i == entriesBeforeLast
			getarray relOffset 0 0
			math nextOffset + relOffset
		endif
		xmath size "nextOffset - offset"
	endif
	string name p "%04d." i
	log name offset size
next

Files in DATA.PAC are compressed with LZSS however it was a bit custom (decompressing it with regular lzss0 will causing the file to come out broken).
Here's the WIP script if someone want to take a crack on it
 

# Neon Genesis Evangelion - Eva and Her Funny Friends: Stripping Complementary Plan! (PC) WIP decompressor script by BloodRaynare
# For use with QuickBMS

comtype lzss "12 4 2 2 0"
get compSize long
get size long
savepos offset
get name basename
string name p "%s." name
clog name offset compSize size

 

Edited April 16, 20242 yr by BloodRaynare